Преобразовать этот cuRL в CFHTTP — Azure NotificationHub

Я пытаюсь получить толчок от сценария ColdFusion с помощью API-интерфейса REST Azure. Там находится рабочий скрипт PHP Вот и я попытался преобразовать PHP в ColdFusion. Ниже приведен код, который у меня есть, и все мне кажется правильным, я не получаю никаких ошибок. Тем не менее, результат в cfhttp.FileContent — просто пустая строка, и я не получаю уведомления. Кто-нибудь может указать на мою ошибку?

    <cfset CONNECTION_STRING = "Endpoint=sb://mypushnamespacehere.servicebus.windows.net/;SharedAccessKeyName=DefaultFullSharedAccessSignature;SharedAccessKey=mysharedaccesskeyhere">
<cfset API_VERSION = "?api-version=2015-01">
<cfset connectionStringParts = ListToArray(CONNECTION_STRING,';','YES')>
<cfset ENDPOINT = "https" & #connectionStringParts[1].substring(11)#>
<cfset HUBPATH = "myhubpathname">
<cfset sasKEYNAME = #connectionStringParts[2].substring(20)#>
<cfset sasKEYVALUE = #connectionStringParts[3].substring(16)#>

<cfset URI = #ENDPOINT# & #HUBPATH# & "/messages" & API_VERSION>

<cfset TARGET_URI = #Lcase(URLEncodedFormat(URI))#>
<cfset EXPIRES = int(createObject('java', 'java.lang.System').currentTimeMillis()/1000)>
<cfset EXPIRES_IN_MINS = 60>
<cfset EXPIRES = EXPIRES + EXPIRES_IN_MINS * 60>

<cfset TO_SIGN = #TARGET_URI# & Chr(13) & Chr(10) & #EXPIRES#>
<cfset SIGNATURE_HMAC = #HMAC(TO_SIGN, sasKEYVALUE, 'HmacSHA256')#>
<cfset SIGNATURE = #EncodeForURL(binaryEncode(binaryDecode(SIGNATURE_HMAC, 'hex'), 'base64'))#>

<cfset TOKEN = "SharedAccessSignature sr=" & #TARGET_URI# & "&sig=" & #SIGNATURE# & "&se=" & #EXPIRES# & "&skn=" & #sasKEYNAME#>

<cftry>
<!--- Create our requestBody --->
<cfset requestBody = '{
"data" : {
"message" : "Hello from ColdFusion"}
}'>
<!--- Send Push --->
<cfhttp method="post" url="#URI#">
<cfhttpparam type="header" name="Authorization" value="#TOKEN#">
<cfhttpparam type="header" name="Content-Type" value="application/json">
<cfhttpparam type="header" name="ServiceBusNotification-Format" value="gcm">
<cfhttpparam type="body" encoded="false" value="#trim(requestBody)#">
</cfhttp>
<!--- Parse JSON Response to determine if call was successful --->
<cfdump var=#cfHttp.FileContent#>
<!--- Catch any errors, return false --->
<cfcatch type="any">
<cfdump var=#cfcatch#>
</cfcatch>
</cftry>

ОБНОВИТЬ

Я протестировал, используя SIGNATURE, который генерирует PHP-скрипт, и он работал из ColdFusion. То, что я генерирую переменную SIGNATURE, не соответствует тому, как это генерирует PHP.

Вот что делает PHP …

$targetUri = strtolower(rawurlencode(strtolower($uri)));
$expires = time();
$expiresInMins = 60;
$expires = $expires + $expiresInMins * 60;
$toSign = $targetUri . "\n" . $expires;

$signature = rawurlencode(base64_encode(hash_hmac('sha256', $toSign, $this->sasKeyValue, TRUE)));

$token = "SharedAccessSignature sr=" . $targetUri . "&sig=" . $signature . "&se=" . $expires . "&skn=" . $this->sasKeyName;

2

Решение

Догадаться.
В PHP «\ n» для новой строки работает нормально, но когда я преобразовывал его в ColdFusion, я использовал Chr (13) & Chr (10). Взял Chr (13) и использовал только Chr (10), и теперь он отлично работает.

обновленный

<cfset TO_SIGN = TARGET_URI & Chr(13) & Chr(10) & EXPIRES>

в

<cfset TO_SIGN = TARGET_URI & Chr(10) & EXPIRES>
3

Другие решения

Других решений пока нет …

По вопросам рекламы ammmcru@yandex.ru
Adblock
detector