Процедура прерывания Arduino для запуска процесса с медленной задержкой

TL; DR — см. Ответ Ника. 🙂

Без полного кода я могу только догадываться о нескольких вещах:

1) Вы не должны ждать в ISR. Даже звонит millis() не рекомендуется, так как это зависит от вызова ISR Timer0, который будет предотвращен, пока вы находитесь в openadoor ISR.

2) В общем, ISR должен делать только очень быстрые вещи … мыслить микросекундами. Это десятки или сотни инструкций, которые могут быть всего лишь несколькими строками кода. Четное digitalWrite почти слишком медленно Если есть еще что сделать, вы должны просто установить volatile флаг, который смотрят в loop, затем loop может сделать трудоемкую работу.

3) Расчет прошедшего времени должен быть в такой форме:

if (millis() - startTime >= DESIRED_TIME)

где startTime тот же тип, что и millis(), uint32_t:

uint32_t startTime;

Ты устанавливаешь startTime Где это уместно:

startTime = millis();

Это позволяет избежать проблемы опрокидывания, когда millis() переворачивается с 2³²-1 в 0.

4) Похоже, вы знаете, как «блокировать», пока не истечет определенное время: while петля будет держать ваш эскиз в этой точке. Если вы просто измените его на if Заявление, Arduino может продолжать свой путь, чтобы справиться с другими вещами.

Так как loop происходит так быстро, if Заявление будет проверять время очень часто … если вы delay или заблокировать где-нибудь еще, как wait_for_esp_response, 🙁 То, что в то время как цикл должен измениться на if заявление также. Рутина больше похожа check_for_esp_response,

5) Вы должны отслеживать состояние процесса открытия и закрытия двери. Это Конечный автомат проблема. Ник имеет хорошее описание Вот, тоже. Вы можете использовать enum введите, чтобы определить состояния, в которых может находиться дверь: ЗАКРЫТО, ОТКРЫТО, ОТКРЫТО и ЗАКРЫТО.

Когда нажата кнопка ОТКРЫТЬ, вы можете посмотреть на состояние и посмотреть, стоит ли его открывать. Затем запустите таймер, включите реле и, самое главное, установите состояние на ОТКРЫТО. В следующий раз через loop, вы можете проверить состояние (а switch заявление), а для случая ОТКРЫТИЯ посмотрите на время, чтобы увидеть, было ли оно достаточно длинным. Если он установил состояние на ОТКРЫТО. И так далее.

Если я включу все эти вещи в ваш эскиз, он должен начать выглядеть так:

volatile bool doorOpenPressed = false;
volatile bool doorClosePressed = false;

static const uint32_t DOOR_OPEN_TIME  = 30000UL; // ms
static const uint32_t DOOR_CLOSE_TIME = 30000UL; // ms
static const uint32_t DATA_SAMPLE_TIME = 60000UL; // ms

static uint32_t lastDataTime, sentTime, relayChanged;

static bool waitingForResponse = false;
static uint8_t responseLen = 0;

enum doorState_t { DOOR_CLOSED, DOOR_OPENING, DOOR_OPENED, DOOR_CLOSING };
doorState_t doorState = DOOR_CLOSED;

void setup()
{
attachInterrupt(4 , openadoor, FALLING);
}

void loop()
{
//  Is it time to take another sample?

if (millis() - lastDataTime > DATA_SAMPLE_TIME) {
lastDataTime = millis();
gathersomedata();

//  You may want to read all Serial2 input first, to make
//  sure old data doesn't get mixed in with the new response.
senddatatoESP();
sentTime = millis();

waitingForResponse = true;
responseLen = 0; // ready for new response
}

//  If we're expecting a response, did we get it?

if (waitingForResponse) {
if (check_for_esp_response("OK")) {
// Got it!
lightGreenLED();
waitingForResponse = false;

} else if (millis() - sentTime > 2000UL) {
// Too long!
lightRedLED();
waitingForResponse = false;

} // else, still waiting
}

// Check and handle the door OPEN and CLOSE buttons,
//   based on the current door state and time

switch (doorState) {

case DOOR_CLOSED:
if (doorOpenPressed) {
digitalWrite(DoorOpenRelay, LOW);
relayChanged = millis();
doorState = DOOR_OPENING;
}
break;

case DOOR_OPENING:
//  Has the door been opening long enough?
if (millis() - relayChanged > DOOR_OPEN_TIME) {
digitalWrite(DoorOpenRelay, HIGH);
doorState = DOOR_OPENED;

} else if (!doorOpenPressed && doorClosePressed) {
// Oops, changed their mind and pressed the CLOSE button.

// You may want to calculate a relayChanged time that
//   is set back from millis() based on how long the
//   door has been opening.  If it just started opening,
//   you probably don't want to drive the relay for the
//   full 30 seconds.
...
}
break;

case DOOR_OPENED:
if (doorClosePressed) {
...
}
break;

case DOOR_CLOSING:
if (millis() - relayChanged > DOOR_CLOSE_TIME) {
...
}
break;
}
}

void openadoor()
{
doorOpenPressed = true;
}

bool check_for_esp_response(const char* term)
{
bool found = false;

if (Serial2.available()) {
// You should make sure you're not running off the end
//   of "buffer" here!
buffer[responseLen++] = Serial2.read();

int len = strlen(term);
if (responseLen >= len) {
if (strncmp(buffer + responseLen - len, term, len) == 0) {
found = true;
}
}
}

return found;
}

Ключ в том, что вы нигде не блокируете и не задерживаетесь. loop вызывается снова и снова, и он просто проверяет несколько переменных. Большую часть времени делать нечего. Но иногда, основываясь на состоянии или текущем времени, он собирает некоторые данные, отправляет их, читает ответ и открывает или закрывает дверь. Эти действия не мешают друг другу, потому что нет блокировки while петли, только быстрые проверки с if заявления.