парсинг — грамматика BNF для простого примера программы на c ++

Поэтому я пытаюсь написать грамматику для простой программы на C ++.

вот как выглядит грамматика прямо сейчас:

PDefs. Program ::= [Def] ;
terminator Def "" ;
comment "//" ;
comment "/*" "*/" ;
comment "#" ;
DFun. Def ::= Type Id "(" [Arg] ")" "{" [Stm] "}" ;
separator Arg "," ;
terminator Stm "" ;
ADecl. Arg ::= Type Id ;
SExp. Stm ::= Exp ";" ;
SDecl. Stm ::= Type Id ";" ;
SDecls. Stm ::= Type Id "," [Id] ";" ;
SInit. Stm ::= Type Id "=" Exp ";" ;
SReturn. Stm ::= "return" Exp ";" ;
SWhile. Stm ::= "while" "(" Exp ")" Stm ;
SBlock. Stm ::= "{" [Stm] "}" ;
SIfElse. Stm ::= "if" "(" Exp ")" Stm "else" Stm ;EInt. Exp15 ::= Integer ;
EDouble. Exp15 ::= Double ;
ETrue. Exp15 ::= "true" ;
EFalse. Exp15 ::= "false" ;
EId. Exp15 ::= Id ;
EApp. Exp15 ::= Id "(" [Exp] ")" ;
EPIncr. Exp14 ::= Exp15 "++" ;
EPDecr. Exp14 ::= Exp15 "--" ;
EIncr. Exp13 ::= "++" Exp14 ;
EDecr. Exp13 ::= "--" Exp14 ;
ETimes. Exp12 ::= Exp12 "*" Exp13 ;
EDiv. Exp12 ::= Exp12 "/" Exp13 ;
EPlus. Exp11 ::= Exp11 "+" Exp12 ;
EMinus. Exp11 ::= Exp11 "-" Exp12 ;
ELt. Exp9 ::= Exp9 "<" Exp10 ;
EGt. Exp9 ::= Exp9 ">" Exp10 ;
ELtEq. Exp9 ::= Exp9 "<=" Exp10 ;
EGtWq. Exp9 ::= Exp9 ">=" Exp10 ;
EEq. Exp8 ::= Exp8 "==" Exp9 ;
ENEq. Exp8 ::= Exp8 "!=" Exp9 ;
EAnd. Exp4 ::= Exp4 "&&" Exp5 ;
EOr. Exp3 ::= Exp3 "||" Exp4 ;
EAss. Exp2 ::= Exp3 "=" Exp2 ;

coercions Exp 15 ;
separator Exp "," ;
separator Id "," ;

Tbool. Type ::= "bool" ;
Tdouble. Type ::= "double" ;
Tint. Type ::= "int" ;
Tvoid. Type ::= "void" ;

token Id (letter (letter | digit | '_')*) ;

и это простая программа C ++, которая должна быть проанализирована

// a small C++ program
#include <iostream>

int main()
{
std::cout << "Hello, world!" << std::endl;
return 0;
}

поэтому, когда я пытаюсь разобрать его, я получаю сообщение об ошибке в строке 6, означающее строку std :: cout. Так как я новичок в BNF, я не знаю, как «думать», чтобы решить эту проблему. Если бы кто-то мог привести пример того, как вы решите подобную ситуацию, было бы здорово.

Спасибо!

1

Решение

Строка, в которой происходит сбой, не может быть проанализирована, потому что вам не хватает некоторых правил:

  1. Вам нужно правило для разбора квалифицированные идентификаторы.
    Квалифицированный идентификатор — это особый тип идентификатора, который может (для ваших целей) использоваться в тех же ситуациях, что и (неквалифицированный) идентификатор.
    std::cout а также std::endl это квалифицированные идентификаторы, и (упрощенное) правило для них может выглядеть примерно так:

    <qualified_id> ::= <nested_name_specifier> <unqualified_id>
    <nested_name_specifier> ::= <namespace_name> "::" <nested_name_specifier>?
    

    в котором (для ваших целей), <unqualified_id> а также <namespace_name> можно рассматривать как идентификаторы.

  2. Вам нужно правило для разбора выражения с помощью << оператор.
    (Упрощенное) правило для этого дополнительного типа выражения может выглядеть примерно так:

    <shift_left_expression> ::= <other_expression>
    <shift_left_expression> ::= <shift_left_expression> "<<" <other_expression>
    

    в котором (для ваших целей) <other_expression> обозначает любой другой тип выражения.

  3. Вам нужно правило для разбора строковые литералы.
    Строковый литерал — это тип литерала, и он может использоваться (для ваших целей) как часть выражения, например, как идентификатор.
    "Hello, world!" является строковым литералом, и (упрощенное) правило для них может выглядеть примерно так:

    <string_literal> ::= "\"" <s_char_sequence>? "\""<s_char_sequence> ::= <s_char>
    <s_char_sequence> ::= <s_char_sequence> <s_char>
    

    в котором <s_char> любой символ, который вы хотите разрешить внутри строкового литерала (для простоты, не позволяйте " характер там, например.).

0

Другие решения


По вопросам рекламы ammmcru@yandex.ru
Adblock
detector